/*

     This file is part of Combean.

     Combean is free software; you can redistribute it and/or modify

     it under the terms of the GNU General Public License as published by

     the Free Software Foundation; either version 2 of the License, or

     (at your option) any later version.

     Combean is distributed in the hope that it will be useful,

     but WITHOUT ANY WARRANTY; without even the implied warranty of

     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

     GNU General Public License for more details.

     You should have received a copy of the GNU General Public License

     along with Foobar; if not, write to the Free Software

     Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA

 */

 package net.sourceforge.combean.test.mathprog.grooml.solvers;

 import net.sourceforge.combean.mathprog.grooml.GroomlInterpreter;

 abstract class AbstractTestSupportedSolver extends GroovyTestCase {

     private GroomlInterpreter builder;

     void setUp() {

         this.builder = new GroomlInterpreter();

     }

     public abstract String solverId();

     /**

      * Sample application: Assign workers to days. Maximize the number

      * of assignments to preferred days.

      */

     protected static final workers = ["alice", "bob", "carol"];

     protected static final weekdays = ["mon", "tue", "wed", "thu", "fri"];

     protected static final preferredDays = [

                                           alice : ["mon", "tue", "thu"],

                                           bob: ["fri"],

                                           carol : ["tue", "wed", "fri"]

                                           ];

     protected int assignmentScore(String worker, String weekday) {

         if (preferredDays[worker].contains(weekday)) {

             return 1;

         }

         return 0;

     }

     protected void checkAssignmentProblem() {

         builder.load{

             solver(solverId())

             // Problem formulated as minimization problem because the

             // Osi-interface of SYMPHONY has a bug with min/max-handling

             min()

             // Indicator variables x[w,d]: assign day d to worker w

             vars("x", [w:workers, d:weekdays]) { -assignmentScore(w, d) }

             // Every day is assigned exactly one worker

             rows("coverdays", [d:weekdays]) {

                 [ sum([w:workers]) { "x[$w,$d]"}, "= 1" ]

             }

             // Every worker gets at most two tasks

             rows("maxtasks", [w:workers]) {

                 [ sum([d:weekdays]) { "x[$w,$d]"}, "<= 2" ]

             }

         }

         builder.solve();

         Map assignment = [:];

         builder.solutions("x").each{ key, val ->

                 if (val > 0.5) {

                     assignment[key[1]] = key[0];

                 }

         }

 //        weekdays.each{ d -> println "$d: ${assignment[d]}" }

 //        print "#satisfied preferences: ${-builder.solutionValue()}"

         assertEquals([mon:"alice", tue:"carol", wed:"carol", thu:"alice", fri:"bob"],

                 assignment);

     }

 }